Using "Inatal-Bat" file from 2011 file

[Don6218]

Hello, I am trying to install the Original v3.0 F unit set by 3Dtrains, GN repaint by Ron Pauldon. I realize that this file is from 2011, but is there a trick to utilize the Instal-Bat command in Win10? I am running:
Edition Windows 10 HomeVersion 22H2
Installed on ‎2021-‎09-‎06
OS build 19045.2728
Experience Windows Feature Experience Pack 120.2212.4190.0 and I cannot get the Bat file to run, even using Admin Level. The window shows, but when I press any key, it just disappears. I installed the files in with the other 3DTrains F-Units, as stated to do. Any suggestions?
Thank you in advance.

[crstagg]

Hummmmm Runs OK in Win 11

[eric]

That's the risk of running batch files from an icon... I usually run troublesome batch files using the Command Prompt tool (Windows-R and then "cmd") and navigating to the applicable folder.

By running in a command prompt window, you'll see the output that's currently disappearing for you. There used to be a way to force the batch file window not to close on exit, but I can't seem to find that option anymore.

[crstagg]

.........

By running in a command prompt window, you'll see the output that's currently disappearing for you. There used to be a way to force the batch file window not to close on exit, but I can't seem to find that option anymore.

Place "PAUSE" at end of the file.

[eric]

There's a dependency with that batch file -- it's looking for the following folder and shape:

\3DTrains_FSkin_NYC\AUnitSkin_NYC_1821.s

If you don't have that, then you'll probably have to pick apart the batch file, find similarly named files in other directories and copy those into your GN directories.

[rdayt]

There could also be an issue with trying to write to a protected Windows folder.
Where do you have your trains installed?

Randy

[Don6218]

I think you hit on the issue, I do not have that one installed. I have a bunch, but not the NYC unit.

I will hunt about for another GN Set. Thank you for your help on this.

[eric]

I think you hit on the issue, I do not have that one installed. I have a bunch, but not the NYC unit.

It's not hard to edit the batch file and replace it with something else you have.

I don't have the NYC set, but I do have the MILW....

Swapping out "NYC_1821.s" with "MILW_88c.s" and changing the folder from "3DTrains_FSkin_NYC" to "3DTrains_FSkin_MILW" worked in my case.


Try this as a replacement for Install.bat and edit the "Source" details about 10 lines down:

@echo off

rem ********* Replaceable Parameters ***********

SET AUNIT=AUnitSkin_GN_352A.s
SET BUNIT=BUnitSkin_GN_352B.s

rem **** replace sourceF with the reporting mark of the railroad e.g. MILW, NYC, etc. that you already have in your folder
SET SOURCEF=MILW

rem **** replace sourceA with the road number of the A unit
SET SOURCEA=88C

rem **** replace sourceB with the road number of the B unit
SET SOURCEB=95B

rem **** Make sure there are no extra spaces before or after the Source variables above!!! ****


rem ********************************************
rem ******* DO NOT EDIT BELOW THIS LINE ********
rem ********************************************

rem **************** File Check ****************

if exist .\..\3DTrains_FSkin_%SOURCEF%\AUnitSkin_%SOURCEF%_%SOURCEA%.s goto A1_Main
goto error

rem **************** File Copy ****************

:A1_Main
md Cabview
call copy .\..\3DTrains_FSkin_%SOURCEF%\A1_Alpha.ace A1_Alpha.ace /y
call copy A1_Alpha.ace B1_Alpha.ace  /y
call copy .\..\3DTrains_FSkin_%SOURCEF%\Options\Hide_Grille.ace A1_Grille.ace /y
call copy A1_Grille.ace B1_Grille.ace  /y
call copy .\..\3DTrains_FSkin_%SOURCEF%\Options\Show_Wire.ace A1_Wire.ace /y
call copy A1_Wire.ace B1_Wire.ace /y
call copy .\..\3DTrains_FSkin_%SOURCEF%\*.txt *.txt
call copy .\..\3DTrains_FSkin_%SOURCEF%\AUnitSkin_%SOURCEF%_%SOURCEA%.s %AUNIT% /y
call copy .\..\3DTrains_FSkin_%SOURCEF%\BUnitSkin_%SOURCEF%_%SOURCEB%.s %BUNIT% /y
call copy .\..\3DTrains_FSkin_%SOURCEF%\A1_Engineer.ace A1_Engineer.ace /y
call copy .\..\3DTrains_FSkin_%SOURCEF%\A1_Fireman.ace A1_Fireman.ace /y
call copy .\..\3DTrains_FSkin_%SOURCEF%\A1_Flag.ace A1_Flag.ace /y
call copy .\..\3DTrains_FSkin_%SOURCEF%\Options\Freeware.cvf .\Cabview\3DTrains_FUnit.cvf /y
call xcopy .\..\3DTrains_FSkin_%SOURCEF%\Options\Show*.ace .\Options\*.* /s /y
call xcopy .\..\3DTrains_FSkin_%SOURCEF%\Options\Hide*.ace .\Options\*.* /s /y
call xcopy .\..\3DTrains_FSkin_%SOURCEF%\Options\*.bat .\Options\*.* /s /y
call copy .\Options\512_A1.ace A1_Main.ace /y
call copy .\Options\512_B1.ace B1_Main.ace /y

rem **************** Cleanup ****************

del .\Options\*.eng
del .\Options\*.cvf
del .\Options\use_*.bat
del .\Options\*_Grille.ace
del .\Options\*_Wire.ace
goto success

rem **************** Messages ****************

:error
echo \3DTrains_FSkin_%SOURCEF%\AUnitSkin_%SOURCEF%_%SOURCEA%.s
echo You MUST have the 3DTrains F-Unit freeware set installed to use this reskin!
pause
goto end

:success
echo Reskin install successful!
pause


:end